tim laqua dot com Thoughts and Code from Tim Laqua

'********************************************************
'* amazonSellerFeedback.vbs
'* Tim Laqua, 2008
'* 
'* Usage: amazonSellerFeedback.vbs SELLERID[,SELLERID[,SELLERID,[...]]]
'********************************************************
Set http = createObject("Microsoft.XMLHTTP")
Set regEx = New RegExp
regEx.IgnoreCase = True
regEx.Global = True
 
' Get the Seller(s) from the command line
Set objArgs = WScript.Arguments
If objArgs.Count < 1 Then
  WScript.Echo "Please specify seller ID"
  WScript.Quit
End If
 
' We allow multiple sellers separated by commas, so split the sellers on a comma
arrSellers = Split(objArgs.Item(0), ",")
 
' Loop for each seller
For Each strSeller in arrSellers
  WScript.Echo "Processing Seller: " & strSeller
  intPage = 1
 
  ' This pattern identifies a single feedback record
  strRecordPattern = "<b>(\d)</b> out of <b>(\d)</b>.*?" & _
                            "<span class=""small"">(.*?)<br />.*?" & _
                            "Date:\s+(\d\d?/\d\d?/\d{4}).*?" & _
                            "Rated by Buyer: (.*?)<"
 
  intTimerStart = Timer
 
  ' Create the output file
  strFileName = "amazonSellerFeedback_" & strSeller & ".csv"
  Set objFSO = CreateObject("Scripting.FileSystemObject")
  Set objTextFile = objFSO.CreateTextFile(strFileName, True)
 
  ' Write column headers
  objTextFile.WriteLine "Seller,Rating,Comment,Date,User"
 
  ' Populate strFeedbackText with first feedback page
  strFeedbackText = getFeedback(intPage)
  regEx.Pattern = strRecordPattern
 
  ' Keep going until the page doesn't have any feedback records on it
  Do While regEx.Test(strFeedbackText)
    Wscript.Echo "Processing records " & intPage*25 & "-" & (intPage+1)*25
 
    Set colMatches = regEx.Execute(strFeedbackText)
    For Each objMatch in colMatches
      strRecord = strSeller & "," & _
            objMatch.SubMatches(0) & "," & _
            """" & Replace(Trim(objMatch.SubMatches(2)),"""","""""") & """," & _
            Trim(objMatch.SubMatches(3)) & "," & _
            """" & Replace(Trim(objMatch.SubMatches(4)),"""","""""") & """"
 
      'Write record to file
      objTextFile.WriteLine(strRecord)
 
    Next
    intPage = intPage + 1
    strFeedbackText = getFeedback(intPage)
    regEx.Pattern = strRecordPattern
  Loop 
 
  WScript.Echo "Processing Finished..." & vbCrLf
  objTextFile.Close
 
  ' Stats and status messages
  WScript.Echo "Data Saved to " & strFileName
  intProcTime = Timer - intTimerStart
  WScript.Echo "Processing Time: " & intProcTime & " seconds"
  WScript.Echo "Per Record Time: " & Round(intProcTime/((intPage - 1)*25), 4)
Next
 
' Function to retreive a a given feedback page for the current strSeller
Function getFeedback(intFeedbackPage)
  strURL =   "http://www.amazon.com/gp/help/seller/feedback.html?" & _
        "ie=UTF8&" & _
        "asin=0471789569&" & _
        "pageNumber=" & intPage & "&" & _
        "seller=" & strSeller
 
  http.open "GET", strURL, False
  http.send
 
  regEx.Pattern = "\n|\r|\t"
  strMungedResponse = regEx.Replace(http.responseText, "")
 
  getFeedback = strMungedResponse
End Function