How to add a calculated measure (calculated field) to an Excel 2007 PivotTable with a SSAS data source

Tim — Wed, 05 Nov 2008 18:28:12 +0000

As it turns out, you can do it programatically as explained by Allan Folting here:
Microsoft Excel: Common Questions Around Excel 2007 OLAP PivotTables:
http://blogs.msdn.com/excel/archive/2008/02/05/common-questions-around-excel-2007-OLAP-PivotTables.aspx

And the parts that I have to keep looking up (I use my blog as a notebook for things I don't want to forget :

Sub AddCalculatedMeasure() 
	Dim pvt As PivotTable
	Dim strName As String
	Dim strFormula As String 
 
	Set pvt = Sheet1.PivotTables("PivotTable1")
	strName = "[Measures].[Internet Sales Amount 25 %]"
	strFormula = "[Measures].[Internet Sales Amount]*1.25"
	pvt.CalculatedMembers.Add Name:=strName, Formula:=strFormula, Type:=xlCalculatedMember 
End Sub 
 
Sub AddCalculatedMember() 
	Dim pvt As PivotTable
	Dim strName As String
	Dim strFormula As String 
 
	Set pvt = Sheet1.PivotTables("PivotTable1")
	strName = "[Product].[Product Categories].[Bikes].[Mountain Bikes].[Mountain-100 Silver, 38 25 %]"
	strFormula = "[Product].[Product Categories].[Bikes].[Mountain Bikes].[Mountain-100 Silver, 38]*1.25"
	pvt.CalculatedMembers.Add Name:=strName, Formula:=strFormula, Type:=xlCalculatedMember
	pvt.ViewCalculatedMembers = True 
End Sub 
 
Sub AddNamedSet() 
	Dim pvt As PivotTable
	Dim strName As String
	Dim strFormula As String
	Dim cbf As CubeField 
 
	Set pvt = Sheet1.PivotTables("PivotTable1")
	strName = "[My Mountain Bikes]"
	strFormula = "[Product].[Product Categories].[Bikes].[Mountain Bikes].children"
	pvt.CalculatedMembers.Add Name:=strName, Formula:=strFormula, Type:=xlCalculatedSet
	Set cbf = pvt.CubeFields.AddSet(Name:="[My Mountain Bikes]", Caption:="Mountain Bikes") 
End Sub

He also mentions that you can expose these members to Excel Services 2007 by creating the new objects and then removing the VBA code - very useful article.

Changing Server Names in Excel 2007 Embedded Workbook Connections

Tim — Mon, 29 Sep 2008 19:59:44 +0000

Ok, so you want to migrate servers, eh? Well - all your business users pry have a couple thousand Pivot Reports lying around that point to the old server. We need to point all references to the old server at the new server.

There are two places these references exist (afaik) - The My Data Sources folder (Windows XP / Excel 2007) which holds all of the odc objects for the logged in user, and the real pain - Embedded data sources in Excel Workbooks.

For the odc objects - you can just loop through the My Data Sources folder files and do a little find/replace action.

For the Excel files - we need to first find all the files, then loop through them and hunt for embedded Connections. Once we find a connection, we can just blindly replace occurrences of the old server name with the new server name. The first thing we need here is a function we can call recursively to go hunt down all the excel files - then we loop through and play with the connections (when found).

Let me know how it goes! Here's the full version:

Set regEx = New RegExp
regEx.IgnoreCase = True
regEx.Global = True
Set WshShell = Wscript.CreateObject("Wscript.Shell")
strMyDocsPath = WshShell.RegRead("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\Personal")
strDataSourceDir = strMyDocsPath & "\My Data Sources"
 
'======================== Fix all the Data Sources
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set Folder = objFSO.GetFolder(strDataSourceDir)
Set Files = Folder.Files
 
For Each File In Files
	If LCase(Right(File.Name, 4)) = ".odc" Then
	    Set objReadFile = objFSO.OpenTextFile(File.Path, 1)
	    strContents = ""
 
		Do While Not objReadFile.AtEndOfStream
			strContents = strContents & objReadFile.ReadLine & vbCrLf
		Loop
 
	    objReadFile.Close
 
		regEx.Pattern = "(?=.*Data Source=OldCrappyServerName.*)(.+)"
 
		If regEx.Test(strContents) Then
			Set colMatches = regEx.Execute(strContents)
 
			For Each objMatch in colMatches
				strOldConnectionString = objMatch.SubMatches(0)
				regEx.Pattern = "Data Source=OldCrappyServerName"
				strNewConnectionString = regEx.Replace(strOldConnectionString, "Data Source=NewAwesomeServerName")
				regEx.Pattern = strOldConnectionString
				strContents = regEx.Replace(strContents, strNewConnectionString)
			Next
 
			Set objWriteFile = objFSO.CreateTextFile(File.Path, True)
			objWriteFile.Write strContents
			objWriteFile.Close
		End If
	End If
Next
 
 
'================================ Fix all the embeded connections (yikes)

Set arrFileList = CreateObject( "System.Collections.ArrayList" )
Set objExcel = CreateObject("Excel.Application")
objExcel.DisplayAlerts = False
 
populateExcelFileList(strMyDocsPath)
 
For Each strFileName In arrFileList
	objExcel.Workbooks.Open(strFileName)
	Set objWorkbook = objExcel.Workbooks(1)
	For Each objWorkbook in objExcel.Workbooks
		If objWorkbook.Connections.Count > 0 Then
			WScript.Echo strFileName
			For Each objConnection in objWorkbook.Connections
				strOldConnection =  objConnection.OLEDBConnection.Connection
				regEx.Pattern = "OldCrappyServerName"
				strNewConnection = regEx.Replace(strOldConnection, "NewAwesomeServerName")
				objConnection.OLEDBConnection.Connection = strNewConnection
			Next
 
		End If
 
		objWorkbook.Close True
	Next
 
	objExcel.Quit
Next
 
Function populateExcelFileList(path)
	Set pathFolder = objFSO.GetFolder(path)
	Set pathFiles = pathFolder.Files
	For Each pathSubFolder in pathFolder.SubFolders
		populateExcelFileList(pathSubFolder.Path)
	Next
 
	For Each pathFile in pathFiles
		If (LCase(Right(pathFile.Name, 5)) = ".xlsx" _
			Or LCase(Right(pathFile.Name, 4)) = ".xls") _
			And Left(pathFile.Name, 1) <> "~" Then
			arrFileList.Add pathFile.Path
		End If
	Next
End Function

Update
I added in support for .xls files - doing this against .xls files can (and usually will) break backwards compatibility for SSAS Pivot Tables.

tim laqua dot com » excel

How to add a calculated measure (calculated field) to an Excel 2007 PivotTable with a SSAS data source

Changing Server Names in Excel 2007 Embedded Workbook Connections