Automating PowerPivot Data Refresh in Sharepoint 2010

Tim — Fri, 16 Mar 2012 00:56:57 +0000

Of course we want to do this, it's a fundamental requirement. Dear Sharepoint, please refresh my PowerPivot when the data is ready, not on some arbitrary schedule. Until this functionality is built-in, people will continue to hack away at it to figure out how to make this happen. Is this supported? Certainly not - so continue at your own risk.

So the method we'll be using here is just to mimic what Sharepoint does when you check the box to "Also refresh as soon as possible" in the schedule configuration page. To accomplish this we open the profiler, connect it to whatever instance our Sharepoint PowerPivot database is hosted on and filter you TextData to "%Schedule%" or filter to just the Sharepoint PowerPivot database (SP2010_PowerPivot_Service_Application in our case) - then open up your test PowerPivot schedule configuration, check the box, click OK, wait for the schedule history to come back up and then stop the trace. Now you know you've got what you need, you just have to find it:

So here we have Sharepoint asking for information about the schedule (identified by the ItemID from DataRefresh.Items) and then passing the data it received to PersistSchedule. If you take a close look at the PersistSchedule parameters, the last one is @RunNow = 1. So clearly, this is what we're after. We went the most tedious route and manually looked up the ItemID in DataRefresh.Items:

SET NOCOUNT ON
 
DECLARE @ItemID UNIQUEIDENTIFIER = '30D39B0E-DA8B-489B-A713-3B29D208B51F'
 
DECLARE
	@ItemName [NVARCHAR](200),
	@SPSiteID [UNIQUEIDENTIFIER],
	@SPWebID [UNIQUEIDENTIFIER],	
	@LastModifiedBy [NVARCHAR](450),
	@ScheduleLastUpdatedBy [NVARCHAR](450),
	@UserIdentity [NVARCHAR](450),
	@EmailNotification [BIT], 
	@EmailList [NVARCHAR](450),
	@SecurityConfiguration [INT],
	@SSApplicationID [NVARCHAR](256),
	@ProcessAllDataSources [BIT],
	@RV [BIGINT],
	-- Schedule info
	@Enabled [BIT], 
	-- Schedule details
	@NextProcessDate [DATETIME],
	@ScheduleStartDate [DATETIME],
	@FrequencyKey [NCHAR](1),
	@RepeatFrequency [INT],
	@Sunday [BIT],
	@Monday [BIT],
	@Tuesday [BIT],
	@Wednesday [BIT],
	@Thursday [BIT],
	@Friday [BIT],
	@Saturday [BIT],
	@Weekday [BIT], 
	@WeekendDay [BIT], 
	@DAY [BIT], 
	@MonthlyPeriod [TINYINT], 
	@MonthlySpecificDay [INT], 
	@ProcessAfterBusinessHours [BIT], 
	@SpecificTime [DATETIME],
	@RunNow [BIT]
 
DECLARE @Schedule TABLE (
	[ItemID] [UNIQUEIDENTIFIER] NOT NULL,
	[Enabled] [BIT] NOT NULL,
	[RV] [BIGINT] NULL,
	[ItemName] [NVARCHAR](200) NOT NULL,
	[SPSiteID] [UNIQUEIDENTIFIER] NOT NULL,
	[SPWebID] [UNIQUEIDENTIFIER] NOT NULL,
	[UserIdentity] [NVARCHAR](450) NULL,
	[LastModifiedBy] [NVARCHAR](450) NOT NULL,
	[EmailNotification] [BIT] NOT NULL,
	[EmailList] [NVARCHAR](450) NULL,
	[SecurityConfiguration] [INT] NOT NULL,
	[SSApplicationID] [NVARCHAR](256) NULL,
	[ProcessAllDataSources] [BIT] NOT NULL,
	[ScheduleDetailID] [UNIQUEIDENTIFIER] NOT NULL,
	[ScheduleStartDate] [DATETIME] NOT NULL,
	[FrequencyKey] [NCHAR](1) NOT NULL,
	[RepeatFrequency] [INT] NOT NULL,
	[Sunday] [BIT] NOT NULL,
	[Monday] [BIT] NOT NULL,
	[Tuesday] [BIT] NOT NULL,
	[Wednesday] [BIT] NOT NULL,
	[Thursday] [BIT] NOT NULL,
	[Friday] [BIT] NOT NULL,
	[Saturday] [BIT] NOT NULL,
	[WeekDay] [BIT] NOT NULL,
	[WeekendDay] [BIT] NOT NULL,
	[DAY] [BIT] NOT NULL,
	[MonthlyPeriod] [TINYINT] NOT NULL,
	[MonthlySpecificDay] [INT] NOT NULL,
	[ProcessAfterBusinessHours] [BIT] NOT NULL,
	[SpecificTime] [DATETIME] NULL
)
 
INSERT INTO @Schedule
EXEC DataRefresh.GetSchedule @ItemID
 
SELECT 
	 @ItemName = [ItemName]
	,@SPSiteID = [SPSiteID]
	,@SPWebID = [SPWebID]
	,@LastModifiedBy = [LastModifiedBy]
	,@ScheduleLastUpdatedBy = N'DOMAIN\tlaqua'
	,@UserIdentity = [UserIdentity]
	,@EmailNotification = [EmailNotification]
	,@EmailList = [EmailList]
	,@SecurityConfiguration = [SecurityConfiguration]
	,@SSApplicationID = [SSApplicationID]
	,@ProcessAllDataSources = [ProcessAllDataSources]
	,@RV = [RV]
		-- Schedule info
	,@Enabled = [Enabled]
		-- Schedule details
	,@NextProcessDate = CAST(GETDATE() AS DATE)
	,@ScheduleStartDate = [ScheduleStartDate]
	,@FrequencyKey = [FrequencyKey]
	,@RepeatFrequency = [RepeatFrequency]
	,@Sunday = [Sunday]
	,@Monday = [Monday]
	,@Tuesday = [Tuesday]
	,@Wednesday = [Wednesday]
	,@Thursday = [Thursday]
	,@Friday = [Friday]
	,@Saturday = [Saturday]
	,@Weekday = [Weekday]
	,@WeekendDay = [WeekendDay]
	,@DAY = [DAY]
	,@MonthlyPeriod = [MonthlyPeriod]
	,@MonthlySpecificDay = [MonthlySpecificDay]
	,@ProcessAfterBusinessHours = [ProcessAfterBusinessHours]
	,@SpecificTime = [SpecificTime]
	,@RunNow = 1
FROM @Schedule
 
EXEC DataRefresh.PersistSchedule
	 @ItemID = @ItemID
	,@ItemName = @ItemName
	,@SPSiteID = @SPSiteID
	,@SPWebID = @SPWebID
	,@LastModifiedBy = @LastModifiedBy
	,@ScheduleLastUpdatedBy = @ScheduleLastUpdatedBy
	,@UserIdentity = @UserIdentity
	,@EmailNotification = @EmailNotification
	,@EmailList = @EmailList
	,@SecurityConfiguration = @SecurityConfiguration
	,@SSApplicationID = @SSApplicationID
	,@ProcessAllDataSources = @ProcessAllDataSources
	,@RV = @RV
		-- Schedule info
	,@Enabled = @Enabled
		-- Schedule details
	,@NextProcessDate = @NextProcessDate
	,@ScheduleStartDate = @ScheduleStartDate
	,@FrequencyKey = @FrequencyKey
	,@RepeatFrequency = @RepeatFrequency
	,@Sunday = @Sunday
	,@Monday = @Monday
	,@Tuesday = @Tuesday
	,@Wednesday = @Wednesday
	,@Thursday = @Thursday
	,@Friday = @Friday
	,@Saturday = @Saturday
	,@Weekday = @Weekday
	,@WeekendDay = @WeekendDay
	,@DAY = @DAY
	,@MonthlyPeriod = @MonthlyPeriod
	,@MonthlySpecificDay = @MonthlySpecificDay
	,@ProcessAfterBusinessHours = @ProcessAfterBusinessHours
	,@SpecificTime = @SpecificTime
	,@RunNow = @RunNow

The only parameters that don't come from GetSchedule are NextRunDate which we set to midnight of today and RunNow which is, of course, 1 and ScheduleLastModifiedBy (I just tossed my username in there, I assume you could use the system identity as well).

And then we set it up to refresh every 10 minutes via Agent job to test:

Happy refreshing! Let me know if you have any questions.

Locating All Checked Out Excel Documents in SharePoint (WSS 3.0)

Tim — Tue, 07 Oct 2008 18:12:53 +0000

SELECT 
	DirName,
	LeafName,
	tp_Email, 
	CheckoutDate, 
	IsCheckoutToLocal
FROM     
	AllDocs d WITH(nolock) 
	INNER JOIN Webs w WITH(nolock) ON d.WebId = w.Id
	INNER JOIN Sites s WITH(nolock) ON w.SiteId = s.Id
	INNER JOIN UserInfo u WITH(nolock) ON (s.Id=u.tp_SiteID AND u.tp_ID=CheckoutUserId)
WHERE
	d.Type <> 1 
	AND (LeafName LIKE '%.xls' OR LeafName LIKE '%.xlsx') 
	AND (LeafName NOT LIKE '%template%')
	AND DeleteTRansactionId = CAST(0 AS VARBINARY)
	AND IsCurrentVersion = 1
	AND IsCheckoutToLocal = 1
ORDER BY
	tp_Email ASC

tim laqua dot com » sharepoint

Automating PowerPivot Data Refresh in Sharepoint 2010

Locating All Checked Out Excel Documents in SharePoint (WSS 3.0)