CREATE TABLE #Temp_SpSpaceUsed
	([name] VARCHAR(255)
	,[rows] INT
	,[reserved] VARCHAR(255)
	,[DATA]	VARCHAR(255)
	,[index_size] VARCHAR(255)
	,[unused] VARCHAR(255)
	,[CreatedTime] DATETIME DEFAULT GETDATE())
 
EXEC sp_msforeachtable 'INSERT INTO #Temp_SpSpaceUsed ([name],[rows],[reserved],[data],[index_size],[unused]) EXEC sp_spaceused [?]'
 
WAITFOR DELAY '00:01:00'
 
EXEC sp_msforeachtable 'INSERT INTO #Temp_SpSpaceUsed ([name],[rows],[reserved],[data],[index_size],[unused]) EXEC sp_spaceused [?]'
 
;WITH SpSpaceUsed AS
(
	SELECT 
		[name]
		,CAST(LEFT([DATA], LEN([DATA]) - 2) AS INT) AS [DATA]
		,[CreatedTime]
		,ROW_NUMBER() OVER (PARTITION BY [name] ORDER BY [CreatedTime] ASC) AS [RowNumber]
	FROM #Temp_SpSpaceUsed	
)
SELECT 
	 a.[name]
	,b.DATA - a.DATA AS [GrowthKB]
	,(CAST(b.DATA - a.DATA AS FLOAT) / DateDiff(MILLISECOND, a.CreatedTime, b.CreatedTime)) * 1000.0 * 60.0 * 60.0 AS [GrowthKBPerHour]
FROM SpSpaceUsed a
	INNER JOIN SpSpaceUsed b
		ON a.[name] = b.[name]
			AND a.RowNumber = 1
			AND b.RowNumber = 2
ORDER BY
	GrowthKBPerHour DESC
 
DROP TABLE #Temp_SpSpaceUsed

EXEC SP_CONFIGURE 'show advanced options' , 1;
GO
RECONFIGURE;
GO
DECLARE @spConfigureOutput TABLE
	([name] VARCHAR(255)
	,[minimum] INT
	,[maximum] INT
	,[config_value] INT
	,[run_value] INT)
 
INSERT INTO @spConfigureOutput
EXEC SP_CONFIGURE
 
SELECT	'EXEC sp_configure ''' + name + ''', ' + CAST(config_value AS VARCHAR)
FROM	@spConfigureOutput
GO
EXEC SP_CONFIGURE 'show advanced options' , 0;
GO
RECONFIGURE;
GO

EXEC SP_CONFIGURE 'show advanced options' , 1;
GO
RECONFIGURE;
GO
 
EXEC SP_CONFIGURE 'Ad Hoc Distributed Queries', 1
EXEC SP_CONFIGURE 'Agent XPs', 1
EXEC SP_CONFIGURE 'clr enabled', 1
EXEC SP_CONFIGURE 'cost threshold for parallelism', 5
EXEC SP_CONFIGURE 'cursor threshold', -1
EXEC SP_CONFIGURE 'Database Mail XPs', 1
EXEC SP_CONFIGURE 'default full-text language', 1033
EXEC SP_CONFIGURE 'default trace enabled', 1
EXEC SP_CONFIGURE 'fill factor (%)', 80
EXEC SP_CONFIGURE 'ft crawl bandwidth (max)', 100
EXEC SP_CONFIGURE 'ft notify bandwidth (max)', 100
EXEC SP_CONFIGURE 'max full-text crawl range', 4
EXEC SP_CONFIGURE 'max server memory (MB)', 10000
EXEC SP_CONFIGURE 'max text repl size (B)', 65536
EXEC SP_CONFIGURE 'min memory per query (KB)', 1024
EXEC SP_CONFIGURE 'min server memory (MB)', 10000
EXEC SP_CONFIGURE 'nested triggers', 1
EXEC SP_CONFIGURE 'network packet size (B)', 4096
EXEC SP_CONFIGURE 'PH timeout (s)', 60
EXEC SP_CONFIGURE 'query wait (s)', -1
EXEC SP_CONFIGURE 'remote access', 1
EXEC SP_CONFIGURE 'remote login timeout (s)', 20
EXEC SP_CONFIGURE 'remote query timeout (s)', 900
EXEC SP_CONFIGURE 'scan for startup procs', 1
EXEC SP_CONFIGURE 'server trigger recursion', 1
EXEC SP_CONFIGURE 'SMO and DMO XPs', 1
 
EXEC SP_CONFIGURE 'show advanced options' , 0;
RECONFIGURE;
GO;

SET NOCOUNT ON
 
DECLARE @MoveOption AS TABLE
	([Id] INT IDENTITY(1,1)
	,[MoveOption] VARCHAR(MAX))
 
PRINT 'RESTORE DATABASE ' + DB_NAME(DB_ID())
-- Edit this to match where you're restoring from
PRINT 'FROM DISK = ''' + DB_NAME(DB_ID()) + '.bak'''  
PRINT 'WITH'
 
INSERT INTO @MoveOption ([MoveOption])
SELECT
    'MOVE ''' + a.name + ''' TO ''' + a.FILENAME + '''' AS [MOVE OPTION]
FROM
    dbo.sysfiles a
 
DECLARE 
	 @LastId INT = 0
	,@MoveOptionText VARCHAR(MAX)
 
WHILE EXISTS (SELECT TOP 1 1 FROM @MoveOption WHERE [Id] > @LastId)
BEGIN
	SELECT 		TOP 1
			 @MoveOptionText = [MoveOption] 
			,@LastId = [Id]
	FROM		@MoveOption
	WHERE		[Id] > @LastId
	ORDER BY	[Id] ASC
 
	PRINT CASE WHEN @LastId = 1 THEN '' ELSE ',' END + @MoveOptionText
END
 
PRINT 'GO'
 
PRINT 'ALTER DATABASE ' + DB_NAME(DB_ID()) + ' SET MULTI_USER'
PRINT 'GO'

RESTORE DATABASE AdventureWorksDW
FROM DISK = 'AdventureWorksDW.bak'
WITH
MOVE 'AdventureWorksDW_Data' TO 'D:\AdventureWorksDW\AdventureWorksDW_Data.mdf'
,MOVE 'AdventureWorksDW_Log' TO 'T:\AdventureWorksDW\AdventureWorksDW_Log.LDF'
GO
ALTER DATABASE AdventureWorksDW SET MULTI_USER
GO

param(
   [string] $ServerName, 		<# The name of the Analysis Services Instance #>
   [string] $DatabaseName, 		<# The name of the Database our Cube is in #>
   [string] $CubeName,     		<# The name of the Cube that our Measure Group is in #>
   [string] $MeasureGroupName, 	<# The name of the Measure Group that our Partition is in #>
   [string] $SourcePartitionName, 	<# The name of the Partition we want to merge in to another partition #>
   [string] $NewPartitionName, 	<# The desired name of the new partition #>
   [string] $NewPartitionQuery 	<# The Query source for the new partition (will use the same datasource as the SourcePartition #>
)
 
[System.Reflection.Assembly]::LoadWithPartialName("Microsoft.AnalysisServices") >$NULL
 
$server = New-Object Microsoft.AnalysisServices.Server
$server.Connect($ServerName)
 
$database = $server.Databases.GetByName($DatabaseName)
$cube = $database.Cubes.GetByName($CubeName)
$measureGroup = $cube.MeasureGroups.FindByName($MeasureGroupName)
$sourcePartition = $measureGroup.Partitions.GetByName($SourcePartitionName)
$sourceQueryBinding = $sourcePartition.Source
 
$newPartition = $sourcePartition.Clone()
$newPartition.ID = $NewPartitionName
$newPartition.Name = $NewPartitionName
$measureGroup.Partitions.Add($newPartition) > $NULL
$newPartition.Source = New-Object Microsoft.AnalysisServices.QueryBinding($sourceQueryBinding.DataSourceID, $NewPartitionQuery)
$newPartition.Update()
 
$server.Disconnect()

SET ANSI_NULLS ON
GO
 
SET QUOTED_IDENTIFIER ON
GO
 
/*************************************************************************************
***
*** Procedure:  		[Utility_CloneSSASPartition]
*** Purpose:		Executes PowerShell script to clone a SSAS partition
***			
***			
*** Author:		tl
*** Date Created:		2010-01-15
*** 
*** Revision History
*** Date		Author			Description
*** 2010-01-15	tl			Created
*************************************************************************************/
 
CREATE PROCEDURE [dbo].[Utility_CloneSSASPartition_S01]
(
	@ServerName AS VARCHAR(255),
	@DatabaseName AS VARCHAR(255),
	@CubeName AS VARCHAR(255),
	@MeasureGroupName AS VARCHAR(255),
	@SourcePartitionName AS VARCHAR(255),
	@NewPartitionName AS VARCHAR(255),
	@NewPartitionQuery AS VARCHAR(255)
)
AS 
 
SET NOCOUNT ON
DECLARE @cmd VARCHAR(8000)
SET @cmd = 
	'powershell.exe -Command "& {'
	+ ' C:\cloneSSASPartition.ps1'
	+ ' -ServerName:\"' + @ServerName + '\"'
	+ ' -DatabaseName:\"' + @DatabaseName + '\"'
	+ ' -CubeName:\"' + @CubeName + '\"'
	+ ' -MeasureGroupName:\"' + @MeasureGroupName + '\"'
	+ ' -SourcePartitionName:\"' + @SourcePartitionName + '\"'
	+ ' -NewPartitionName:\"' + @NewPartitionName + '\"'
	+ ' -NewPartitionQuery:\"' + @NewPartitionQuery + '\"}"'
 
PRINT @cmd
EXEC xp_cmdshell @cmd

EXEC [dbo].[Utility_CloneSSASPartition_S01]
	 @ServerName = 'TESTSERVER'
	,@DatabaseName = 'TestDatabase'
	,@CubeName = 'TestCube'
	,@MeasureGroupName = 'Test Measure Group'
	,@SourcePartitionName = 'Test Partition - 200912'
	,@NewPartitionName = 'Test Partition - 201001'
	,@NewPartitionQuery = 'SELECT * FROM dbo.FactTableMonth(''1/1/2010'', ''2/1/2010'')'

DECLARE @JobName VARCHAR(255) = 'Agent Job Name'
 
;WITH JobHistory AS
(
  SELECT
     a.run_date
    ,a.run_time / 10000 AS [HOUR]
    ,(a.run_duration / 10000 * 60 * 60	-- Hours
     + a.run_duration % 10000 / 100 * 60	-- Minutes
     + a.run_duration % 100			-- Seconds
     ) / 60.0 AS [DurationMinutes]
  FROM
    msdb.dbo.sysjobhistory a WITH(NOLOCK)
    INNER JOIN msdb.dbo.sysjobs b WITH(NOLOCK)
    ON 
      a.[job_id] = b.[job_id]
      AND b.[name] = @JobName
      AND step_id = 0
      AND run_status = 1
)
SELECT *
FROM
  JobHistory	
  PIVOT
  ( SUM(DurationMinutes)
    FOR [HOUR] 
    IN  ([00],[01],[02],[03],[04],[05]
        ,[06],[07],[08],[09],[10],[11]
        ,[12],[13],[14],[15],[16],[17]
        ,[18],[19],[20],[21],[22],[23])
  ) AS p

SELECT 
	 percent_complete AS [PercentComplete]
	,estimated_completion_time/1000.0/60.0 AS [RemainingMinutes]
	,total_elapsed_time/1000.0/60.0 AS [ElapsedMinutes]
	,(estimated_completion_time+total_elapsed_time)/1000.0/60.0 AS [TotalMinutes]
	,DATEADD(MILLISECOND, estimated_completion_time, GETDATE()) AS [EstimatedTimeOfCompletion]
	,st.TEXT AS [CommandSQL]
FROM sys.dm_exec_requests r
	cross apply sys.dm_exec_sql_text(r.sql_handle) st
WHERE command LIKE '%RESTORE DATABASE%'

 
DECLARE @DBName VARCHAR(64) = 'databasename'
 
DECLARE @ErrorLog AS TABLE([LogDate] CHAR(24), [ProcessInfo] VARCHAR(64), [TEXT] VARCHAR(MAX))
 
INSERT INTO @ErrorLog
EXEC sys.xp_readerrorlog 0, 1, 'Recovery of database', @DBName
 
SELECT TOP 5
	 [LogDate]
	,SUBSTRING([TEXT], CHARINDEX(') is ', [TEXT]) + 4,CHARINDEX(' complete (', [TEXT]) - CHARINDEX(') is ', [TEXT]) - 4) AS PercentComplete
	,CAST(SUBSTRING([TEXT], CHARINDEX('approximately', [TEXT]) + 13,CHARINDEX(' seconds remain', [TEXT]) - CHARINDEX('approximately', [TEXT]) - 13) AS FLOAT)/60.0 AS MinutesRemaining
	,CAST(SUBSTRING([TEXT], CHARINDEX('approximately', [TEXT]) + 13,CHARINDEX(' seconds remain', [TEXT]) - CHARINDEX('approximately', [TEXT]) - 13) AS FLOAT)/60.0/60.0 AS HoursRemaining
	,[TEXT]
 
FROM @ErrorLog ORDER BY [LogDate] DESC

CREATE TABLE #Temp_SCDInserts ([PartId] INT)
 
-- INSERTS for new Parts
INSERT INTO #Temp_SCDInserts
SELECT   
	[PartId]
FROM 
	Part a WITH(NOLOCK)
	INNER JOIN PartType b WITH(NOLOCK) 
		ON a.PartTypeId = b.PartTypeId
	INNER JOIN PartSupplier c WITH(NOLOCK) 
		ON a.PartSupplierId = c.PartSupplierId
	INNER JOIN PartSupplierCategory d WITH(NOLOCK) 
		ON c.PartSupplierCategoryId = d.PartSupplierCategoryId
EXCEPT
SELECT
	[PartId]	
FROM
	DW.dbo.Dim_Part WITH(NOLOCK)
 
-- UPDATES
SELECT 
	 dim.[PartKeyId]
	,a.[PartName]
	,b.[PartTypeId]
	,b.[PartTypeName]
	,c.[PartSupplierId]
	,c.[PartSupplierName]
	,d.[PartSupplierCategoryId]
	,d.[PartSupplierCategoryName]
INTO #Temp_SCDUpdates
FROM DW.dbo.Dim_Part dim WITH(NOLOCK)
	INNER JOIN Part a WITH(NOLOCK)
		ON dim.PartId = a.PartId -- Business Key
	INNER JOIN PartType b WITH(NOLOCK) 
		ON a.PartTypeId = b.PartTypeId
	INNER JOIN PartSupplier c WITH(NOLOCK) 
		ON a.PartSupplierId = c.PartSupplierId
	INNER JOIN PartSupplierCategory d WITH(NOLOCK) 
		ON c.PartSupplierCategoryId = d.PartSupplierCategoryId
WHERE
	dim.PartName <> a.PartName
	OR dim.PartTypeId <> b.PartTypeId
	OR dim.PartTypeName <> b.PartTypeName
	OR dim.PartSupplierId <> c.PartSupplierId
	OR dim.PartSupplierName <> c.PartSupplierName
	OR dim.PartSupplierCategoryId <> d.PartSupplierCategoryId
	OR dim.PartSupplierCategoryName	<> d.PartSupplierCategoryName
 
-- INSERT new records
INSERT INTO [DW].[dbo].[Dim_Part]
	([PartId]
	,[PartName]
	,[PartTypeId]
	,[PartTypeName]
	,[PartSupplierId]
	,[PartSupplierName]
	,[PartSupplierCategoryId]
	,[PartSupplierCategoryName])
SELECT 
	 a.[PartId]
	,a.[PartName]
	,b.[PartTypeId]
	,b.[PartTypeName]
	,c.[PartSupplierId]
	,c.[PartSupplierName]
	,d.[PartSupplierCategoryId]
	,d.[PartSupplierCategoryName]
FROM #Temp_SCDInserts i
	INNER JOIN Part a WITH(NOLOCK)
		ON i.PartId = a.PartId -- Business Key
	INNER JOIN PartType b WITH(NOLOCK) 
		ON a.PartTypeId = b.PartTypeId
	INNER JOIN PartSupplier c WITH(NOLOCK) 
		ON a.PartSupplierId = c.PartSupplierId
	INNER JOIN PartSupplierCategory d WITH(NOLOCK) 
		ON c.PartSupplierCategoryId = d.PartSupplierCategoryId
 
-- UPDATE existing records
UPDATE [DW].[dbo].[Dim_Part]
SET
	 [PartName] = b.[PartName]
	,[PartTypeId] = b.[PartTypeId]
	,[PartTypeName] = b.[PartTypeName]
	,[PartSupplierId] = b.[PartSupplierId]
	,[PartSupplierName] = b.[PartSupplierName]
	,[PartSupplierCategoryId] = b.[PartSupplierCategoryId]
	,[PartSupplierCategoryName] = b.[PartSupplierCategoryName]
FROM 
	[DW].[dbo].[Dim_Part] AS a
	INNER JOIN #Temp_SCDUpdates AS b 
		ON a.PartKeyId = b.PartKeyId  -- Join on Business Keys or Surrogate Key
 
 
DROP TABLE #Temp_SCDInserts
DROP TABLE #Temp_SCDUpdates

SELECT
	a.[Id],
	b.[GetVariableValue] AS [Foo],
	c.[GetVariableValue] AS [Bar]
FROM
	[dbo].[SourceTable] a
	CROSS APPLY [dbo].[Utility_UrlParseGetVariable_F01]([URL], 'foo', 0) b
	CROSS APPLY [dbo].[Utility_UrlParseGetVariable_F01]([URL], 'bar', 0) c

/*************************************************************************************
***
*** Procedure:  		[Utility_UrlParseGetVariable_F01]
*** Purpose:		    Attempts to parse a given GET variable out of a URL string
***				
***			
*** Author:		      tl
*** Date Created:	  2009-05-22
*** 
*** Revision History
*** Date		Author			Description
*** 2009-05-22	tl				Created
*************************************************************************************/
ALTER FUNCTION [dbo].[Utility_UrlParseGetVariable_F01] 
(
	@Url VARCHAR(2048),
	@VariableName VARCHAR(255)
)
RETURNS @GetVariable TABLE ([GetVariableValue] VARCHAR(255))
AS
BEGIN
 
	DECLARE @SUBSTRING VARCHAR(2048)
	DECLARE @variableValue VARCHAR(255)
 
	SET @VariableName = @VariableName + '='
 
	-- Case Insensitive - munge both inputs
	SET @VariableName = LOWER(@VariableName)
	SET @Url = LOWER(@Url)
 
	IF (CHARINDEX(@VariableName,@Url) > 0)
	BEGIN
		SET @SUBSTRING = RIGHT(@Url, LEN(@Url) - CHARINDEX(@VariableName,@Url) - LEN(@VariableName) + 1)
		IF (CHARINDEX('&', @SUBSTRING) > 0)
			SET @variableValue = CAST(LEFT(@SUBSTRING, CHARINDEX('&', @SUBSTRING) - 1) AS VARCHAR(255))
		ELSE
			SET @variableValue = CAST(@SUBSTRING AS VARCHAR(255))
 
		INSERT INTO @GetVariable ([GetVariableValue]) VALUES (@variableValue)
	END
	ELSE
		INSERT INTO @GetVariable ([GetVariableValue]) VALUES (NULL)
 
	RETURN
END

SELECT
	 DatabaseName
	,ObjectName
	,CAST(query_plan.VALUE('
		declare namespace QP="http://schemas.microsoft.com/sqlserver/2004/07/showplan";   
		sum((/QP:ShowPlanXML/QP:BatchSequence/QP:Batch/QP:Statements/QP:StmtSimple/QP:QueryPlan/@CompileTime))','NVARCHAR(MAX)') AS FLOAT)/1000.0/60.0 AS [CompileTime]
	,query_plan
	,query_plan.VALUE('
		declare namespace QP="http://schemas.microsoft.com/sqlserver/2004/07/showplan";   
		count((//QP:ColumnsWithNoStatistics))','INT') AS [ColumnsWithNoStatistics]
	,query_plan.VALUE('
		declare namespace QP="http://schemas.microsoft.com/sqlserver/2004/07/showplan";   
		count((//QP:TableScan))','INT') AS [TableScan]
	,query_plan.VALUE('
		declare namespace QP="http://schemas.microsoft.com/sqlserver/2004/07/showplan";   
		count((//QP:IndexScan))','INT') AS [IndexScan]
	,query_plan.VALUE('
		declare namespace QP="http://schemas.microsoft.com/sqlserver/2004/07/showplan";   
		count((//QP:RelOp[@PhysicalOp="Nested Loops"]))','INT') AS [NestedLoop]
	,query_plan.VALUE('
		declare namespace QP="http://schemas.microsoft.com/sqlserver/2004/07/showplan";   
		count((//QP:RelOp[@PhysicalOp="Hash Match"]))','INT') AS [HashMatch]
	,query_plan.VALUE('
		declare namespace QP="http://schemas.microsoft.com/sqlserver/2004/07/showplan";   
		count((//QP:RelOp[@PhysicalOp="Merge Join"]))','INT') AS [MergeJoin]
FROM 
	(	
		SELECT
			OBJECT_NAME(st.objectid,st.dbid) AS ObjectName,
			DB_NAME(st.dbid) AS DatabaseName,
			st.dbid,
			st.objectid,
			qs.plan_handle
		FROM 
			sys.dm_exec_query_stats AS qs
			CROSS APPLY sys.dm_exec_sql_text(qs.sql_handle) AS st
		WHERE
			ObjectId IS NOT NULL
		GROUP BY
			st.dbid,
			st.objectid,
			qs.plan_handle
	) a
	CROSS APPLY sys.dm_exec_query_plan(plan_handle) qp
WHERE DatabaseName = 'NameOfDatabase'
ORDER BY DatabaseName, ObjectName