CREATE TABLE #Temp_SpSpaceUsed
	([name] VARCHAR(255)
	,[rows] INT
	,[reserved] VARCHAR(255)
	,[DATA]	VARCHAR(255)
	,[index_size] VARCHAR(255)
	,[unused] VARCHAR(255)
	,[CreatedTime] DATETIME DEFAULT GETDATE())
 
EXEC sp_msforeachtable 'INSERT INTO #Temp_SpSpaceUsed ([name],[rows],[reserved],[data],[index_size],[unused]) EXEC sp_spaceused [?]'
 
WAITFOR DELAY '00:01:00'
 
EXEC sp_msforeachtable 'INSERT INTO #Temp_SpSpaceUsed ([name],[rows],[reserved],[data],[index_size],[unused]) EXEC sp_spaceused [?]'
 
;WITH SpSpaceUsed AS
(
	SELECT 
		[name]
		,CAST(LEFT([DATA], LEN([DATA]) - 2) AS INT) AS [DATA]
		,[CreatedTime]
		,ROW_NUMBER() OVER (PARTITION BY [name] ORDER BY [CreatedTime] ASC) AS [RowNumber]
	FROM #Temp_SpSpaceUsed	
)
SELECT 
	 a.[name]
	,b.DATA - a.DATA AS [GrowthKB]
	,(CAST(b.DATA - a.DATA AS FLOAT) / DateDiff(MILLISECOND, a.CreatedTime, b.CreatedTime)) * 1000.0 * 60.0 * 60.0 AS [GrowthKBPerHour]
FROM SpSpaceUsed a
	INNER JOIN SpSpaceUsed b
		ON a.[name] = b.[name]
			AND a.RowNumber = 1
			AND b.RowNumber = 2
ORDER BY
	GrowthKBPerHour DESC
 
DROP TABLE #Temp_SpSpaceUsed

EXEC SP_CONFIGURE 'show advanced options' , 1;
GO
RECONFIGURE;
GO
DECLARE @spConfigureOutput TABLE
	([name] VARCHAR(255)
	,[minimum] INT
	,[maximum] INT
	,[config_value] INT
	,[run_value] INT)
 
INSERT INTO @spConfigureOutput
EXEC SP_CONFIGURE
 
SELECT	'EXEC sp_configure ''' + name + ''', ' + CAST(config_value AS VARCHAR)
FROM	@spConfigureOutput
GO
EXEC SP_CONFIGURE 'show advanced options' , 0;
GO
RECONFIGURE;
GO

EXEC SP_CONFIGURE 'show advanced options' , 1;
GO
RECONFIGURE;
GO
 
EXEC SP_CONFIGURE 'Ad Hoc Distributed Queries', 1
EXEC SP_CONFIGURE 'Agent XPs', 1
EXEC SP_CONFIGURE 'clr enabled', 1
EXEC SP_CONFIGURE 'cost threshold for parallelism', 5
EXEC SP_CONFIGURE 'cursor threshold', -1
EXEC SP_CONFIGURE 'Database Mail XPs', 1
EXEC SP_CONFIGURE 'default full-text language', 1033
EXEC SP_CONFIGURE 'default trace enabled', 1
EXEC SP_CONFIGURE 'fill factor (%)', 80
EXEC SP_CONFIGURE 'ft crawl bandwidth (max)', 100
EXEC SP_CONFIGURE 'ft notify bandwidth (max)', 100
EXEC SP_CONFIGURE 'max full-text crawl range', 4
EXEC SP_CONFIGURE 'max server memory (MB)', 10000
EXEC SP_CONFIGURE 'max text repl size (B)', 65536
EXEC SP_CONFIGURE 'min memory per query (KB)', 1024
EXEC SP_CONFIGURE 'min server memory (MB)', 10000
EXEC SP_CONFIGURE 'nested triggers', 1
EXEC SP_CONFIGURE 'network packet size (B)', 4096
EXEC SP_CONFIGURE 'PH timeout (s)', 60
EXEC SP_CONFIGURE 'query wait (s)', -1
EXEC SP_CONFIGURE 'remote access', 1
EXEC SP_CONFIGURE 'remote login timeout (s)', 20
EXEC SP_CONFIGURE 'remote query timeout (s)', 900
EXEC SP_CONFIGURE 'scan for startup procs', 1
EXEC SP_CONFIGURE 'server trigger recursion', 1
EXEC SP_CONFIGURE 'SMO and DMO XPs', 1
 
EXEC SP_CONFIGURE 'show advanced options' , 0;
RECONFIGURE;
GO;

SET NOCOUNT ON
 
DECLARE @MoveOption AS TABLE
	([Id] INT IDENTITY(1,1)
	,[MoveOption] VARCHAR(MAX))
 
PRINT 'RESTORE DATABASE ' + DB_NAME(DB_ID())
-- Edit this to match where you're restoring from
PRINT 'FROM DISK = ''' + DB_NAME(DB_ID()) + '.bak'''  
PRINT 'WITH'
 
INSERT INTO @MoveOption ([MoveOption])
SELECT
    'MOVE ''' + a.name + ''' TO ''' + a.FILENAME + '''' AS [MOVE OPTION]
FROM
    dbo.sysfiles a
 
DECLARE 
	 @LastId INT = 0
	,@MoveOptionText VARCHAR(MAX)
 
WHILE EXISTS (SELECT TOP 1 1 FROM @MoveOption WHERE [Id] > @LastId)
BEGIN
	SELECT 		TOP 1
			 @MoveOptionText = [MoveOption] 
			,@LastId = [Id]
	FROM		@MoveOption
	WHERE		[Id] > @LastId
	ORDER BY	[Id] ASC
 
	PRINT CASE WHEN @LastId = 1 THEN '' ELSE ',' END + @MoveOptionText
END
 
PRINT 'GO'
 
PRINT 'ALTER DATABASE ' + DB_NAME(DB_ID()) + ' SET MULTI_USER'
PRINT 'GO'

RESTORE DATABASE AdventureWorksDW
FROM DISK = 'AdventureWorksDW.bak'
WITH
MOVE 'AdventureWorksDW_Data' TO 'D:\AdventureWorksDW\AdventureWorksDW_Data.mdf'
,MOVE 'AdventureWorksDW_Log' TO 'T:\AdventureWorksDW\AdventureWorksDW_Log.LDF'
GO
ALTER DATABASE AdventureWorksDW SET MULTI_USER
GO

;WITH [ProcessEvent] AS
(
SELECT
	'Process' AS [Event]
	,cast([TextData] AS XML).value
		('declare namespace B="http://schemas.microsoft.com/analysisservices/2003/engine";           
		(//B:DatabaseID)[1]'
		,'VARCHAR(1024)') AS [DatabaseID]
	,cast([TextData] AS XML).value
		('declare namespace B="http://schemas.microsoft.com/analysisservices/2003/engine";           
		(//B:DimensionID)[1]'
		,'VARCHAR(1024)') AS [DimensionID]
	,cast([TextData] AS XML).value
		('declare namespace B="http://schemas.microsoft.com/analysisservices/2003/engine";           
		(//B:MeasureGroupID)[1]'
		,'VARCHAR(1024)') AS [MeasureGroupId]
	,[StartTime]
	,[Duration]
FROM dbo.zTrace_MSAS_20091023_2 T
WHERE 
	T.[EventClass] = 16 
	AND T.[EventSubclass] IN (3, 12)
	AND [TextData] LIKE '%Process%'
),
[QueryEvent] AS
(
SELECT
	'Query' AS [Event]
	,[DatabaseName] AS [DatabaseID]
	,NULL AS [DimensionID]
	,NULL AS [MeasureGroupId]
	,[StartTime]
	,[Duration]
FROM dbo.zTrace_MSAS_20091023_2 T
WHERE T.[EventClass] = 10
),
[Event] AS
(
	SELECT * FROM [ProcessEvent]
	UNION
	SELECT * FROM [QueryEvent]
)
SELECT
	 ROW_NUMBER() OVER (ORDER BY [StartTime] ASC) AS [EventId]
	,DATEADD(HOUR, -5, [StartTime]) AS [StartTime]
	,DATEDIFF(MILLISECOND, (SELECT MIN([StartTime]) FROM Event), [StartTime]) [RelativeStartTime]
	,[Duration]
	,[Event]
	,[DatabaseID]
	,CASE
		WHEN [DimensionID] IS NOT NULL THEN 'Dimension'
		WHEN [MeasureGroupID] IS NOT NULL THEN 'Measure Group'
		ELSE 'None'
	 END AS [ObjectType]	,CASE
		WHEN [DimensionID] IS NOT NULL THEN [DimensionID]
		WHEN [MeasureGroupID] IS NOT NULL THEN [MeasureGroupID]
		ELSE 'None'
	 END AS [ObjectId]	
FROM [Event]
WHERE
	DATEDIFF(MILLISECOND, (SELECT MIN([StartTime]) FROM Event), [StartTime]) >= @StartMillisecond
	AND DATEDIFF(MILLISECOND, (SELECT MIN([StartTime]) FROM Event), [StartTime]) < @EndMillisecond
	AND Duration >= @MinDuration

CREATE TYPE TableColumnDefinition AS TABLE
	([DataType] VARCHAR(16) NOT NULL
	,[Length] INT
	,[IsKey] BIT
	,[DataLength] AS
		CASE 
			WHEN [DataType] = 'BIT' THEN 0.125
			WHEN [DataType] = 'TINYINT' THEN 1
			WHEN [DataType] = 'SMALLINT' THEN 2
			WHEN [DataType] IN ('INT', 'SMALLMONEY', 'REAL', 'SMALLDATETIME') THEN 4
			WHEN [DataType] IN ('BIGINT', 'DATETIME', 'MONEY') THEN 8
			WHEN [DataType] = 'UNIQUEIDENTIFIER' THEN 16
			WHEN [DataType] = 'NVARCHAR' THEN [Length] * 2 + 2
			WHEN [DataType] = 'VARCHAR' THEN [Length] + 2	-- DOESN'T SUPPORT MAX
			WHEN [Datatype] = 'DATE' THEN 3 
			WHEN [Datatype] = 'TIME' THEN 5 -- Worst case
			WHEN [Datatype] = 'DATETIME2' THEN 8 -- Worst case
			WHEN [Datatype] = 'DATETIMEOFFSET' THEN 10 -- Worst case
			WHEN [DataType] = 'CHAR' THEN [Length]
			WHEN [DataType] = 'NCHAR' THEN [Length] * 2 + 2
			WHEN [DataType] = 'BINARY' THEN [Length]
			WHEN [DataType] = 'VARBINARY' THEN [Length] + 2
			WHEN [Datatype] = 'TIMESTAMP' THEN 8
			WHEN [DataType] = 'XML' THEN [Length]	-- Estimate an average size in bytes, 2GB max
			WHEN [DataType] IN ('DECIMAL', 'NUMERIC') THEN 
				CASE 
					WHEN [Length] BETWEEN 1 AND 9	THEN 5
					WHEN [Length] BETWEEN 10 AND 19 THEN 9
					WHEN [Length] BETWEEN 20 AND 28 THEN 13
					WHEN [Length] BETWEEN 29 AND 38 THEN 17
				END
			WHEN [DataType] = 'FLOAT' THEN
				CASE
					WHEN [Length] BETWEEN 1 AND 24 THEN 4
					WHEN [Length] BETWEEN 25 AND 53 THEN 8
					WHEN [Length] IS NULL THEN 8	-- Default n is 53
				END
			ELSE 0
		END
	,[IsVariableLength] AS
		CASE 
			WHEN [DataType] IN ('VARCHAR', 'NVARCHAR', 'VARBINARY') THEN 1
			ELSE 0
		END)

/*************************************************************************************
***
*** Procedure:  		[Utility_EstimateClusteredIndexSize]
*** Purpose:		    Estimates the amount of space needed for a given clustered index
*** Methodology:		http://msdn.microsoft.com/en-us/library/ms178085.aspx
***			
***			
*** Author:		      Tim Laqua
*** Date Created:	  2009-10-15 
*** 
*** Revision History
*** Date		Author			Description
*** 2009-10-15	tl				Created
*************************************************************************************/
ALTER PROCEDURE [dbo].[Utility_EstimateClusteredIndexSize]
(
	 @Num_Rows FLOAT
	,@ClusteredIndexIsUnique BIT
	,@Fill_Factor FLOAT
	,@TableColumn TableColumnDefinition READONLY
)
AS 
 
SET NOCOUNT ON
 
DECLARE
	 @Num_Cols FLOAT = 0					-- total number of columns (fixed-length and variable-length)
	,@Fixed_Data_Size FLOAT = 0			-- total byte size of all fixed-length columns
	,@Num_Variable_Cols FLOAT	= 0			-- number of variable-length columns
	,@Max_Var_Size FLOAT	= 0				-- maximum byte size of all variable-length columns
	,@Variable_Data_Size FLOAT = 0
 
DECLARE @VAR TABLE
	([Name] VARCHAR(64)
	,[VALUE] FLOAT
	,[DisplayValue] AS
		CASE
			WHEN LOWER([Name]) LIKE '%size%' OR LOWER([Name]) LIKE '%space%' THEN
				CASE 
					WHEN [VALUE] < 1024 THEN CAST(CAST(ROUND([VALUE], 3) AS NUMERIC(16,0)) AS VARCHAR(16)) + ' B'
					WHEN [VALUE] < 1024*1024 THEN CAST(CAST(ROUND([VALUE]/1024, 3) AS NUMERIC(16,3)) AS VARCHAR(16)) + ' KB'
					WHEN [VALUE] < 1024*1024*1024 THEN CAST(CAST(ROUND([VALUE]/1024/1024, 3) AS NUMERIC(16,3)) AS VARCHAR(16)) + ' MB'
					ELSE CAST(CAST(ROUND([VALUE]/1024/1024/1024, 3) AS NUMERIC(16,3)) AS VARCHAR(16)) + ' GB'
				END
			ELSE CAST(FLOOR([VALUE]) AS VARCHAR(16))
		END)
 
 
-- Leaf level data
SELECT 
	 @Num_Variable_Cols = COUNT(1)
	,@Max_Var_Size = ISNULL(SUM([DataLength]), 0)
FROM @TableColumn WHERE [IsVariableLength] = 1
 
SELECT 
	 @Num_Cols = COUNT(1) + @Num_Variable_Cols
	,@Fixed_Data_Size = CEILING(ISNULL(SUM([DataLength]), 0))
FROM @TableColumn WHERE [IsVariableLength] = 0
 
 
INSERT INTO @VAR VALUES ('@Fixed_Data_Size', @Fixed_Data_Size)
 
IF @ClusteredIndexIsUnique <> 0
BEGIN
	SET @Num_Cols += 1
	IF @Num_Variable_Cols > 0
		SET @Num_Variable_Cols += 1
	IF @Max_Var_Size > 0
		SET @Max_Var_Size += 4
END
 
DECLARE @Null_Bitmap INT = CEILING(2 + ((@Num_Cols + 7) / 8))
INSERT INTO @VAR VALUES ('@Null_Bitmap', @Null_Bitmap)
 
-- if there are variable columns
IF @Num_Variable_Cols > 0
	SET @Variable_Data_Size = 2 + (@Num_Variable_Cols * 2) + @Max_Var_Size 
INSERT INTO @VAR VALUES ('@Num_Cols', @Num_Cols)
INSERT INTO @VAR VALUES ('@Num_Variable_Cols', @Num_Variable_Cols)
INSERT INTO @VAR VALUES ('@Max_Var_Size', @Max_Var_Size)
 
DECLARE @Row_Size FLOAT = CEILING(@Fixed_Data_Size + @Variable_Data_Size + @Null_Bitmap + 4 )
INSERT INTO @VAR VALUES ('@Row_Size', @Row_Size)
 
DECLARE @Rows_Per_Page FLOAT = FLOOR(8096 / (@Row_Size + 2))
INSERT INTO @VAR VALUES ('@Rows_Per_Page', @Rows_Per_Page)
 
DECLARE @Free_Rows_Per_Page FLOAT = FLOOR(8096 * ((100 - @Fill_Factor) / 100) / (@Row_Size + 2) )
INSERT INTO @VAR VALUES ('@Free_Rows_Per_Page', @Free_Rows_Per_Page)
 
DECLARE @Num_Leaf_Pages FLOAT = CEILING(@Num_Rows / (@Rows_Per_Page - @Free_Rows_Per_Page) )
INSERT INTO @VAR VALUES ('@Num_Leaf_Pages', @Num_Leaf_Pages)
 
DECLARE @Leaf_space_used FLOAT = 8192 * @Num_Leaf_Pages
INSERT INTO @VAR VALUES ('@Leaf_space_used', @Leaf_space_used)
 
-- Index Information
DECLARE
	 @Num_Key_Cols FLOAT = 0			-- total number of key columns (fixed-length and variable-length)
	,@Fixed_Key_Size FLOAT = 0			-- total byte size of all fixed-length key columns
	,@Num_Variable_Key_Cols FLOAT = 0	-- number of variable-length key columns
	,@Max_Var_Key_Size FLOAT = 0		-- maximum byte size of all variable-length key columns
 
 
SELECT 
	 @Num_Variable_Key_Cols = COUNT(1)
	,@Max_Var_Key_Size = ISNULL(SUM([DataLength]), 0)
FROM @TableColumn 
WHERE 
	[IsVariableLength] = 1 
	AND [IsKey] = 1
 
SELECT 
	 @Num_Key_Cols = COUNT(1) + @Num_Variable_Key_Cols
	,@Fixed_Key_Size = ISNULL(SUM([DataLength]), 0)
FROM @TableColumn 
WHERE 
	[IsVariableLength] = 0
	AND [IsKey] = 1
 
IF @ClusteredIndexIsUnique <> 0
BEGIN
	SET @Num_Key_Cols += 1
	IF @Num_Variable_Key_Cols > 0
		SET @Num_Variable_Key_Cols += 1
	IF @Max_Var_Key_Size > 0
		SET @Max_Var_Key_Size += 4
END
INSERT INTO @VAR VALUES ('@Num_Variable_Key_Cols', @Num_Variable_Key_Cols)
INSERT INTO @VAR VALUES ('@Max_Var_Key_Size', @Max_Var_Key_Size)
INSERT INTO @VAR VALUES ('@Num_Key_Cols', @Num_Key_Cols)
 
-- Who would seriously have a nullable key column?  ridiculous.
DECLARE @Index_Null_Bitmap FLOAT = 2 + ((@Num_Key_Cols + 7) / 8) 
INSERT INTO @VAR VALUES ('@Index_Null_Bitmap', @Index_Null_Bitmap)
 
DECLARE @Variable_Key_Size FLOAT = 0
 
IF @Max_Var_Key_Size > 0
	SET @Variable_Key_Size = 2 + (@Num_Variable_Key_Cols * 2) + @Max_Var_Key_Size 
INSERT INTO @VAR VALUES ('@Variable_Key_Size', @Variable_Key_Size)
 
DECLARE @Index_Row_Size FLOAT = @Fixed_Key_Size + @Variable_Key_Size + @Index_Null_Bitmap + 1 + 6
INSERT INTO @VAR VALUES ('@Index_Row_Size',@Index_Row_Size )
 
DECLARE @Index_Rows_Per_Page  FLOAT = FLOOR(8096 / (@Index_Row_Size + 2))
INSERT INTO @VAR VALUES ('@Index_Rows_Per_Page', @Index_Rows_Per_Page)
 
DECLARE @Non_Leaf_Levels FLOAT = 1
 
-- Log base @Non_Leaf_Levels hack
WHILE (@Num_Leaf_Pages / @Index_Rows_Per_Page) > POWER(@Index_Rows_Per_Page,@Non_Leaf_Levels)
	SET @Non_Leaf_Levels += 1
 
SET @Non_Leaf_Levels += 1
INSERT INTO @VAR VALUES ('@Non_Leaf_Levels', @Non_Leaf_Levels)
 
-- Summation hack
DECLARE 
	 @Num_Index_Pages FLOAT = 0
	,@Summand INT = @Non_Leaf_Levels
 
WHILE @Summand > 0
BEGIN
	SET @Num_Index_Pages += CEILING(@Num_Leaf_Pages/POWER(@Index_Rows_Per_Page, @Summand))
	SET @Summand -= 1
END
INSERT INTO @VAR VALUES ('@Num_Index_Pages', @Num_Index_Pages)
 
DECLARE @Index_Space_Used FLOAT = 8192 * @Num_Index_Pages 
INSERT INTO @VAR VALUES ('@Index_Space_Used', @Index_Space_Used)
 
DECLARE @Clustered_Index_Size FLOAT = @Leaf_Space_Used + @Index_Space_used
INSERT INTO @VAR VALUES ('@Clustered_Index_Size', @Clustered_Index_Size)
 
SELECT * FROM @VAR

DECLARE @TableColumn TableColumnDefinition
 
INSERT INTO @TableColumn
VALUES 
	 ('UNIQUEIDENTIFIER', NULL, 1)
	,('DATETIME', NULL, 1)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
	,('INT', NULL, 0)
 
EXEC [dbo].[Utility_EstimateClusteredIndexSize]	
 @Num_Rows = 750000		-- number of rows in the table
,@ClusteredIndexIsUnique = 1 	-- is it?
,@Fill_Factor = 90			-- page fill factor
,@TableColumn = @TableColumn	-- definition of table columns

Name                                                             Value                  DisplayValue
---------------------------------------------------------------- ---------------------- -------------------
@Fixed_Data_Size                                                 60                     60 B
@Null_Bitmap                                                     5                      5
@Num_Cols                                                        12                     12
@Num_Variable_Cols                                               0                      0
@Max_Var_Size                                                    0                      0 B
@Row_Size                                                        69                     69 B
@Rows_Per_Page                                                   114                    114
@Free_Rows_Per_Page                                              11                     11
@Num_Leaf_Pages                                                  7282                   7282
@Leaf_space_used                                                 59654144               56.891 MB
@Num_Variable_Key_Cols                                           0                      0
@Max_Var_Key_Size                                                0                      0 B
@Num_Key_Cols                                                    3                      3
@Index_Null_Bitmap                                               3.25                   3
@Variable_Key_Size                                               0                      0 B
@Index_Row_Size                                                  34.25                  34 B
@Index_Rows_Per_Page                                             223                    223
@Non_Leaf_Levels                                                 2                      2
@Num_Index_Pages                                                 34                     34
@Index_Space_Used                                                278528                 272.000 KB
@Clustered_Index_Size                                            59932672               57.156 MB

SELECT [Path], ContentText
FROM
(
SELECT [Path], cast(cast([content]AS varbinary(8000)) AS varchar(8000)) AS [ContentText]
FROM [catalog] cat WITH(nolock)
WHERE [type]=2
) a
WHERE ContentText LIKE '%ColumnName%' 
	OR ContentText LIKE '%columnname%' 
	OR ContentText LIKE '%MeasureName%' 
	OR ContentText LIKE '%AttributeName%' 
	OR ContentText LIKE '%etc...%'